source: src/main.vala @ a3d57aae7735bdde7300b1e663df36ade9dc8e8c

/* main.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using I4uc;

void main (string[] args)
{
        Gtk.init (ref args);
        
        try
        {
                load_settings ();
                load_builders ();
                load_programmers ();
                load_stock_items ();
        }
        catch (GLib.Error e)
        {
                warning (e.message);
        }
        
        Intl.bindtextdomain (Config.GETTEXT_PACKAGE, Config.LOCALE_DIR);
    Intl.bind_textdomain_codeset (Config.GETTEXT_PACKAGE, "UTF-8");
        
        var main_window_view = new MainWindowView ();
        main_window_view.show_all ();
        
        var ui_manager = main_window_view.ui_manager;
        var pages_panel = main_window_view.pages_panel;
        var side_panel = main_window_view.side_panel;
        var bottom_panel = main_window_view.bottom_panel;
        
        var documents_view = new DocumentsView (ui_manager, pages_panel, side_panel);
        var projects_view = new ProjectsView (ui_manager, side_panel, bottom_panel);
        var programmers_view = new ProgrammersView (ui_manager, pages_panel, side_panel, bottom_panel);
        
        var main_window_presenter = new MainWindowPresenter (main_window_view);
        var documents_presenter = new DocumentsPresenter (documents_view);
        var projects_presenter = new ProjectsPresenter (projects_view, documents_presenter);
        var programmers_presenter = new ProgrammersPresenter (programmers_view, documents_presenter);
        
        main_window_view.exit_clicked.connect (() => {
                if (!documents_presenter.close_all ())
                        return true;
                projects_presenter.close_all_projects ();
                return false;
        });
        
        Gtk.main ();
        
        try
        {
                I4uc.Settings.instance.save ();
        }
        catch (GLib.FileError e)
        {
                warning (e.message);
        }
}

void load_settings () throws GLib.Error, GLib.KeyFileError
{
        var settings_folder = Path.build_filename (Environment.get_home_dir (), ".i4uc");
        if (!FileUtils.test (settings_folder, FileTest.EXISTS))
                DirUtils.create (settings_folder, 0755);
        var settings_filename = Path.build_filename (settings_folder, "i4ucrc");
        I4uc.Settings.instance.open (settings_filename);
}

void load_builders () throws GLib.Error, GLib.KeyFileError
{
        //Load builders in $(pkgdatadir)/builders/
        var builders_dir = File.new_for_path (Config.BUILDERS_DIR);
        
        var enumerator = builders_dir.enumerate_children (FILE_ATTRIBUTE_STANDARD_NAME, FileQueryInfoFlags.NONE, null);
        FileInfo file_info;
        while ((file_info = enumerator.next_file (null)) != null)
        {
                if (!file_info.get_name ().has_suffix (".i4ucbuilder"))
                        continue;

                var builder_file = builders_dir.get_child (file_info.get_name ());
                var builder = new I4uc.Builder ();
                if (builder.open (builder_file.get_uri ()))
                        I4uc.Settings.instance.builders[builder.id] = builder;
        }

        //check if $(HOME)/.i4uc/builders/ exists. If not, create it
        builders_dir = File.new_for_path (Path.build_filename (Environment.get_home_dir (), ".i4uc", "builders"));
        if (!builders_dir.query_exists (null))
                builders_dir.make_directory (null);

        //Load builders in $(HOME)/.i4uc/builders/
        enumerator = builders_dir.enumerate_children (FILE_ATTRIBUTE_STANDARD_NAME, FileQueryInfoFlags.NONE, null);
        while ((file_info = enumerator.next_file (null)) != null)
        {
                if (!file_info.get_name ().has_suffix (".i4ucbuilder"))
                        continue;

                var builder_file = builders_dir.get_child (file_info.get_name ());
                var builder = new I4uc.Builder ();
                if (builder.open (builder_file.get_uri ()))
                        I4uc.Settings.instance.builders[builder.id] = builder;
        }
}

void load_programmers () throws GLib.Error, GLib.KeyFileError
{
        //Load programmers in $(pkgdatadir)/programmers/
        var programmers_dir = File.new_for_path (Config.PROGRAMMERS_DIR);
        
        var enumerator = programmers_dir.enumerate_children (FILE_ATTRIBUTE_STANDARD_NAME, FileQueryInfoFlags.NONE, null);
        FileInfo file_info;
        while ((file_info = enumerator.next_file (null)) != null)
        {
                if (!file_info.get_name ().has_suffix (".i4ucprogrammer"))
                        continue;

                var programmer_file = programmers_dir.get_child (file_info.get_name ());
                var programmer = new Programmer ();
                if (programmer.open (programmer_file.get_uri ()))
                        I4uc.Settings.instance.programmers[programmer.id] = programmer;
        }

        //check if $(HOME)/.i4uc/programmers/ exists. If not, create it
        programmers_dir = File.new_for_path (Path.build_filename (Environment.get_home_dir (), ".i4uc", "programmers"));
        if (!programmers_dir.query_exists (null))
                programmers_dir.make_directory (null);

        //Load programmers in $(HOME)/.i4uc/programmers/
        enumerator = programmers_dir.enumerate_children (FILE_ATTRIBUTE_STANDARD_NAME, FileQueryInfoFlags.NONE, null);
        while ((file_info = enumerator.next_file (null)) != null)
        {
                if (!file_info.get_name ().has_suffix (".i4ucprogrammer"))
                        continue;

                var programmer_file = programmers_dir.get_child (file_info.get_name ());
                var programmer = new Programmer ();
                if (programmer.open (programmer_file.get_uri ()))
                        I4uc.Settings.instance.programmers[programmer.id] = programmer;
        }
}

/*
        Load i4uc stock items located in $(pkgdatadir)/pixmaps
*/
void load_stock_items () throws GLib.Error
{
        var icon_factory = new IconFactory ();
        
        var icon_set = new IconSet.from_pixbuf (new Gdk.Pixbuf.from_file (Path.build_filename (Config.PIXMAPS_DIR, "programmer-icon.svg")));
        icon_factory.add ("i4uc-programmer-icon", icon_set);
        
        icon_set = new IconSet.from_pixbuf (new Gdk.Pixbuf.from_file (Path.build_filename (Config.PIXMAPS_DIR, "write-flash.svg")));
        icon_factory.add ("i4uc-write-flash", icon_set);
        
        icon_set = new IconSet.from_pixbuf (new Gdk.Pixbuf.from_file (Path.build_filename (Config.PIXMAPS_DIR, "read-flash.svg")));
        icon_factory.add ("i4uc-read-flash", icon_set);
        
        icon_set = new IconSet.from_pixbuf (new Gdk.Pixbuf.from_file (Path.build_filename (Config.PIXMAPS_DIR, "verify-flash.svg")));
        icon_factory.add ("i4uc-verify-flash", icon_set);
        
        icon_set = new IconSet.from_pixbuf (new Gdk.Pixbuf.from_file (Path.build_filename (Config.PIXMAPS_DIR, "erase-flash.svg")));
        icon_factory.add ("i4uc-erase-flash", icon_set);
        
        icon_factory.add_default ();
}