source: src/i4ucpicstartpluspage.vala @ 5a9774013ee476929436662ebfac36412f4614e9

/* i4ucpicstartpluspage.vala
 *
 * Copyright (C) 2009  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;
#if !ENABLE_WIN32
using DBus;
using Hal;
#endif

public class I4uc.PicstartPlusPage: Page
{
        private PicstartPlus _picstart_plus = new PicstartPlus ();
        private LogsPanel _logs_panel;
        private Log _log = new Log ();
        private ComboBox _connection_port = new ComboBox.text ();
        private Entry _pic_model = new Entry ();
        private Entry _configuration_bits = new Entry ();
        private FileChooserButton _hexfile = new FileChooserButton (_("Select Hexfile to write"), FileChooserAction.OPEN);
        private string _working_directory = Environment.get_home_dir ();
        private RadioButton _programmer_version;
        private RadioButton _erase_flash;
        private RadioButton _write_program;
        private RadioButton _read_program;
        private RadioButton _write_configuration_bits;
        private RadioButton _read_configuration_bits;
        
        public PicstartPlusPage (LogsPanel logs_panel)
        {
                _logs_panel = logs_panel;
                
                _log.title = "PICSTART Plus";
                _log.tab_title = _("PICSTART Plus log");
                _log.headers_visible = false;
                _log.close_action.connect (() => {
                        _logs_panel.remove_log (_log);
                });
                _picstart_plus.message_added.connect ((message) => {
                        _log.add_line (message);
                });
                
                foreach (var device in get_serial_devices ())
                        _connection_port.append_text (device);
                _connection_port.active = 0;
                
                var size_group = new SizeGroup (SizeGroupMode.HORIZONTAL);
                
                var vbox = new VBox (false, 0);
                
                var hbox = create_hbox (_("Connection port:"), size_group, vbox);
                hbox.pack_start (_connection_port, true, true, 5);
                hbox = create_hbox (_("Pic model:"), size_group, vbox);
                hbox.pack_start (_pic_model, true, true, 5);
                
                _programmer_version = new RadioButton.with_label (null, _("Get programmer version"));
                hbox = create_hbox_with_radio_button (_programmer_version, size_group, vbox);
                
                _erase_flash = new RadioButton.with_label_from_widget (_programmer_version, _("Erase flash"));
                hbox = create_hbox_with_radio_button (_erase_flash, size_group, vbox);
                
                _write_program = new RadioButton.with_label_from_widget (_erase_flash, _("Write program"));
                hbox = create_hbox_with_radio_button (_write_program, size_group, vbox);
                hbox.pack_start (_hexfile, true, true, 5);
                var filter = new FileFilter ();
                filter.set_name (_(".hex files"));
                filter.add_pattern ("*.hex");
                _hexfile.add_filter (filter);
                _hexfile.set_current_folder (_working_directory);
                _hexfile.current_folder_changed.connect (() => {
                        _working_directory = _hexfile.get_current_folder ();
                });
                
                _read_program = new RadioButton.with_label_from_widget (_write_program, _("Read program"));
                hbox = create_hbox_with_radio_button (_read_program, size_group, vbox);
                
                _write_configuration_bits = new RadioButton.with_label_from_widget (_read_program, _("Write configuration bits"));
                hbox = create_hbox_with_radio_button (_write_configuration_bits, size_group, vbox);
                hbox.pack_start (_configuration_bits, true, true, 5);
                
                _read_configuration_bits = new RadioButton.with_label_from_widget (_write_configuration_bits, _("Read configuration bits"));
                hbox = create_hbox_with_radio_button (_read_configuration_bits, size_group, vbox);
                
                var run_command = new Button.with_label (_("Run command"));
                run_command.clicked.connect (on_run_command);
                
                hbox = new HBox (false, 0);
                hbox.pack_end (run_command, false, false, 5);
                
                vbox.pack_start (hbox, false, false, 5);
                
                var scrolled_window = new ScrolledWindow (null, null);
                scrolled_window.add_with_viewport (vbox);
                scrolled_window.set_policy (PolicyType.AUTOMATIC, PolicyType.AUTOMATIC);
                
                pack_start (scrolled_window, true, true, 5);
                show_all ();
        }
        
        private void on_run_command ()
        {
                _picstart_plus.connection_port = _connection_port.get_active_text ();
                _picstart_plus.pic_model = _pic_model.text;
                bool log_found = false;
                foreach (var log in _logs_panel.list_logs ())
                        if (log.title == "PICSTART Plus")
                                log_found = true;
                if (!log_found)
                        _logs_panel.add_log (_log);
                if (!_logs_panel.visible)
                        _logs_panel.show ();
                _logs_panel.show_log (_log);
                
                if (_programmer_version.active)
                        _picstart_plus.get_programmer_version ();
                
                if (_erase_flash.active)
                        _picstart_plus.erase_flash ();
                        
                if (_write_program.active)
                        _picstart_plus.write_program (_hexfile.get_filename ());
                
                if (_read_program.active)
                        _picstart_plus.write_program (Path.build_filename (_working_directory, "i4uc-read.hex"));
                
                if (_write_configuration_bits.active)
                        _picstart_plus.write_configuration_bits (_configuration_bits.text);
                
                if (_read_configuration_bits.active)
                        _picstart_plus.read_configuration_bits ();
        }
        
        private HBox create_hbox (string title, SizeGroup size_group, VBox vbox)
        {
                var hbox = new HBox (false, 0);
                var label = new Label (title);
                label.xalign = 1;
                size_group.add_widget (label);
                
                hbox.pack_start (label, false, false, 5);
                vbox.pack_start (hbox, false, false, 5);

                return hbox;
        }
        
        private HBox create_hbox_with_radio_button (RadioButton title, SizeGroup size_group, VBox vbox)
        {
                var hbox = new HBox (false, 0);
                size_group.add_widget (title);
                
                hbox.pack_start (title, false, false, 5);
                vbox.pack_start (hbox, false, false, 5);

                return hbox;
        }
        
        private Gee.List<string> get_serial_devices ()
        {
                #if ENABLE_WIN32
                
                var device_list = new ArrayList<string> (str_equal);
                device_list.add ("COM1");
                device_list.add ("COM2");
                device_list.add ("COM3");
                device_list.add ("COM4");
                
                #else
                
                var dbus_error = DBus.RawError ();
                
                var hal = new Hal.Context ();

                if (hal == null)
                        print ("Error getting HAL context\n");

                if (!hal.set_dbus_connection (RawBus.get (BusType.SYSTEM, ref dbus_error))) 
                        print ("Error setting dbus connection: %s\n".printf (dbus_error.message));
                
                if (!hal.init (ref dbus_error))
                        print ("Cannot initialize connection to the hald\nNormally this means that the HAL deamon (hald) is not running or not ready\n");
                
                var udis = hal.find_device_by_capability ("serial", ref dbus_error);
                if (dbus_error.is_set ()) 
                        print ("Error finding serial devices: %s: %s\n".printf (dbus_error.name, dbus_error.message));
                
                var device_list = new ArrayList<string> (str_equal);
                foreach (string udi in udis)
                {
                        string device;
                        device = hal.device_get_property_string (udi, "serial.device", ref dbus_error);
                        if (dbus_error.is_set ()) 
                                print ("Error getting property string: %s: %s\n".printf (dbus_error.name, dbus_error.message));
                        device_list.add (device);
                }
                
                #endif
                
                return device_list;
        }
}