source: libi4uccore/settings.vala @ 7960aa9d2d3dd725b78cfdaf11e252649be6141f

/* settings.vala
 *
 * Copyright (C) 2009-2011  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class OptionSettings : GLib.Object
{
        public string name { set; get; }
        public string value { set; get; }
        public bool active { set; get; }
        
        public string to_xml (size_t tab_width)
        {
                var prefix = string.nfill (tab_width, '\t');
                var xml_str = "<option_value name=\"%s\" value=\"%s\" active=\"%s\"/>\n";
                return prefix + xml_str.printf (_name, _value, _active.to_string ());
        }
}

public class ProgrammerSettings : GLib.Object
{
        private HashMap<string, OptionSettings> _options = new HashMap<string, OptionSettings> ();
        
        public string name { set; get; }
        public Gee.Map<string, OptionSettings> options { get { return _options; } }
        
        public string to_xml (size_t tab_width)
        {
                var prefix = string.nfill (tab_width, '\t');
                var xml_str = prefix + "<programmer name=\"%s\">\n".printf (_name);
                foreach (var option_settings in _options.values)
                        xml_str += option_settings.to_xml (tab_width+1);
                xml_str += prefix + "</programmer>\n";
                return xml_str;
        }
}

public class I4uc.Core.Settings : GLib.Object
{
        private HashMap<string, ProgrammerSettings> _programmers = new HashMap<string, ProgrammerSettings> ();
        
        public string working_folder { set; get; }
        
        // MainWindow Settings
        public int width { set; get; default = 320; }
        public int height { set; get; default = 240; }
        public bool maximized { set; get; default = false; }
        public bool side_panel_visible { set; get; }
        public bool bottom_panel_visible { set; get; }
        
        // Documents Settings
        public string font { set; get; default = "Monospace 10"; }
        public int tab_width { set; get; default = 8; }
        public bool auto_indent { set; get; }
        public bool highlight_current_line { set; get; }
        public bool insert_spaces_instead_of_tabs { set; get; }
        public bool show_line_numbers { set; get; }
        public bool highlight_matching_brackets { set; get; }
        public bool wrap_mode { set; get; }
        
        // Programmers settings
        public string programmer { set; get; default = ""; }
        public Gee.Map<string, ProgrammerSettings> programmers { get { return _programmers; } }
        
        public Settings ()
        {
                 _working_folder = File.new_for_path (Environment.get_home_dir ()).get_uri ();
        }
        
        public string to_xml ()
        {
                var xml_str = "<settings>\n";
                
                // MainWindow settings
                xml_str += @"\t<width>$(_width)</width>\n";
                xml_str += @"\t<height>$(_height)</height>\n";
                xml_str += @"\t<maximized>$(_maximized)</maximized>\n";
                xml_str += @"\t<side_panel_visible>$(_side_panel_visible)</side_panel_visible>\n";
                xml_str += @"\t<bottom_panel_visible>$(_bottom_panel_visible)</bottom_panel_visible>\n";
                
                // Documents settings
                xml_str += @"\t<font>$(_font)</font>\n";
                xml_str += @"\t<tab_width>$(_tab_width)</tab_width>\n";
                xml_str += @"\t<auto_indent>$(_auto_indent)</auto_indent>\n";
                xml_str += @"\t<highlight_current_line>$(_highlight_current_line)</highlight_current_line>\n";
                xml_str += @"\t<insert_spaces_instead_of_tabs>$(_insert_spaces_instead_of_tabs)</insert_spaces_instead_of_tabs>\n";
                xml_str += @"\t<show_line_numbers>$(_show_line_numbers)</show_line_numbers>\n";
                xml_str += @"\t<highlight_matching_brackets>$(_highlight_matching_brackets)</highlight_matching_brackets>\n";
                xml_str += @"\t<wrap_mode>$(_wrap_mode)</wrap_mode>\n";
                
                // Programmers settings
                xml_str += @"\t<current_programmer>$(_programmer)</current_programmer>\n";
                
                xml_str += "\t<programmers>\n";
                foreach (var programmer in _programmers.values)
                        xml_str += programmer.to_xml (2);
                xml_str += "\t</programmers>\n";
                
                return xml_str + "</settings>";
        }
}