source: libi4uc/i4ucsettings.vala @ b61fc026e7a6957c78c3af4e6b250ad8310431dd

/* i4ucsettings.vala
 *
 * Copyright (C) 2009-2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.Settings : GLib.Object
{
        private const string _I4UC_SETTINGS = "i4uc settings";
        private const string _DOCUMENTS_SETTINGS = "Documents settings";
        private const string _PAGE_SETUP_SETTINGS = "Page setup settings";
        private const string _PRINT_SETTINGS = "Print settings";
        private const string _PICSTART_PLUS_SETTINGS = "Picstart Plus settings";
        private const string _PICKIT2_SETTINGS = "Pickit 2 settings";
        
        private static Settings _instance;
        private string _filename;
        private HashMap<string, Builder> _builders = new HashMap<string, Builder> ();
        
        public bool side_panel_visible { set; get; }
        public bool logs_panel_visible { set; get; }
        public string working_folder { set; get; }
        
        public string documents_font { set; get; default = "Monospace 11"; }
        public int documents_tab_width { set; get; default = 8; }
        public bool documents_auto_indent { set; get; }
        public bool documents_highlight_current_line { set; get; }
        public bool documents_insert_spaces_instead_of_tabs { set; get; }
        public bool documents_show_line_numbers { set; get; }
        public bool documents_highlight_matching_brackets { set; get; }
        public bool documents_wrap_mode { set; get; }
        
        public PageSetup page_setup { set; get; default = new PageSetup (); }
        public PrintSettings print_settings { set; get; default = new PrintSettings (); }
        
        public Gee.Map<string, Builder> builders { get { return _builders; } }
        
        public string picstart_plus_connection_port { set; get; default = ""; }
        public string pickit2_device_file { set; get; default = ""; }
        
        public static Settings instance
        {
                get
                {
                        if (_instance == null)
                                _instance = new Settings ();
                        return _instance;
                }
        }
        
        public Settings ()
        {
                 _working_folder = Filename.to_uri (Environment.get_home_dir ());
        }
        
        public void open (string filename)
        {
                _filename = filename;
                var key_file = new KeyFile ();
                
                if (!FileUtils.test (_filename, FileTest.EXISTS) ||
                    !key_file.load_from_file (_filename, KeyFileFlags.NONE) ||
                    key_file.get_start_group () != _I4UC_SETTINGS)
                        return;
                
                this.side_panel_visible = key_file.get_boolean (_I4UC_SETTINGS, "side_panel_visible");
                this.logs_panel_visible = key_file.get_boolean (_I4UC_SETTINGS, "logs_panel_visible");
                
                this.documents_font = key_file.get_string (_DOCUMENTS_SETTINGS, "font");
                this.documents_tab_width = key_file.get_integer (_DOCUMENTS_SETTINGS, "tab_width");
                this.documents_auto_indent = key_file.get_boolean (_DOCUMENTS_SETTINGS, "auto_indent");
                this.documents_highlight_current_line = key_file.get_boolean (_DOCUMENTS_SETTINGS, "highlight_current_line");
                this.documents_insert_spaces_instead_of_tabs = key_file.get_boolean (_DOCUMENTS_SETTINGS, "insert_spaces_instead_of_tabs");
                this.documents_show_line_numbers = key_file.get_boolean (_DOCUMENTS_SETTINGS, "show_line_numbers");
                this.documents_highlight_matching_brackets = key_file.get_boolean (_DOCUMENTS_SETTINGS, "highlight_matching_brackets");
                this.documents_wrap_mode = key_file.get_boolean (_DOCUMENTS_SETTINGS, "wrap_mode");
                
                if (key_file.has_group (_PAGE_SETUP_SETTINGS))
                        this.page_setup = new PageSetup.from_key_file (key_file, _PAGE_SETUP_SETTINGS);
                
                if (key_file.has_group (_PRINT_SETTINGS))
                        this.print_settings = new PrintSettings.from_key_file (key_file, _PRINT_SETTINGS);
                
                this.picstart_plus_connection_port = key_file.get_string (_PICSTART_PLUS_SETTINGS, "connection_port");
                this.pickit2_device_file = key_file.get_string (_PICKIT2_SETTINGS, "device_file");
        }
        
        public void save ()
        {
                var key_file = new KeyFile ();
                
                key_file.set_boolean (_I4UC_SETTINGS, "side_panel_visible", _side_panel_visible);
                key_file.set_boolean (_I4UC_SETTINGS, "logs_panel_visible", _logs_panel_visible);
                
                key_file.set_string (_DOCUMENTS_SETTINGS, "font", _documents_font);
                key_file.set_integer (_DOCUMENTS_SETTINGS, "tab_width", _documents_tab_width);
                key_file.set_boolean (_DOCUMENTS_SETTINGS, "auto_indent", _documents_auto_indent);
                key_file.set_boolean (_DOCUMENTS_SETTINGS, "highlight_current_line", _documents_highlight_current_line);
                key_file.set_boolean (_DOCUMENTS_SETTINGS, "insert_spaces_instead_of_tabs", _documents_insert_spaces_instead_of_tabs);
                key_file.set_boolean (_DOCUMENTS_SETTINGS, "show_line_numbers", _documents_show_line_numbers);
                key_file.set_boolean (_DOCUMENTS_SETTINGS, "highlight_matching_brackets", _documents_highlight_matching_brackets);
                key_file.set_boolean (_DOCUMENTS_SETTINGS, "wrap_mode", _documents_wrap_mode);
                
                _page_setup.to_key_file (key_file, _PAGE_SETUP_SETTINGS);
                _print_settings.to_key_file (key_file, _PRINT_SETTINGS);
                
                key_file.set_string (_PICSTART_PLUS_SETTINGS, "connection_port", _picstart_plus_connection_port);
                key_file.set_string (_PICKIT2_SETTINGS, "device_file", _pickit2_device_file);
                
                size_t len;
                var str = key_file.to_data (out len);
                FileUtils.set_contents (_filename, str, (long)len);
        }
}