source: libi4uc/i4ucprojectsview.vala @ e7bab963c488e383de4d6c79887ec374f2621765

/* i4ucprojectsview.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.ProjectsView : GLib.Object, ProjectsViewIface
{
        private UIManager _ui_manager;
        private ActionGroup _action_group;
        private SidePanel _side_panel;
        private ProjectsSidePageView _projects_side_page_view = new ProjectsSidePageView ();
        private Action _close_action;

        public ProjectsSidePageViewIface projects_side_page_view { get { return _projects_side_page_view; } }
        
        public bool close_sensitive
        {
                set { _close_action.sensitive = value; }
                get { return _close_action.sensitive; }
        }
        
        public ProjectsView (UIManager ui_manager, SidePanel side_panel)
        {
                _ui_manager = ui_manager;
                _side_panel = side_panel;

                _action_group = new ActionGroup ("I4ucProjectsActions");
                _action_group.add_actions (_action_entries, this);
                
                _ui_manager.insert_action_group (_action_group, -1);
                _ui_manager.add_ui_from_string (_UI, -1);
                
                _close_action = _action_group.get_action ("CloseProjectAction");

                _side_panel.add_page (_projects_side_page_view);
        }

        public void show_error_message (string error_message)
        {
                var message = new MessageDialog (null, DialogFlags.MODAL, MessageType.ERROR, ButtonsType.NONE, error_message);
                message.add_button (STOCK_OK, ResponseType.OK);
                message.set_default_response (ResponseType.OK);
                message.run ();
                message.destroy ();
        }

        public int show_new_dialog (out string project_uri, out string project_name, out Gee.List<string> authors)
        {
                var dialog = new NewProjectDialog ();
                var response = dialog.run ();

                project_uri = dialog.uri;
                project_name = dialog.name;
                authors = dialog.authors;

                dialog.destroy ();
                return response;
        }

        public void show_open_dialog (ref string folder_uri, out Gee.List<string> projects)
        {
                var dialog = new FileChooserDialog (_("Open project"), null, FileChooserAction.OPEN);
                dialog.select_multiple = true;
                dialog.set_current_folder_uri (folder_uri);
                dialog.add_button (STOCK_CANCEL, ResponseType.CANCEL);
                dialog.add_button (STOCK_OPEN, ResponseType.OK);
                dialog.set_default_response (ResponseType.OK);
                var filter = new FileFilter ();
                filter.set_name (_("i4uc projects"));
                filter.add_pattern ("*.i4uc");
                dialog.add_filter (filter);
                
                var uris = new ArrayList<string> ();
                if (dialog.run () == ResponseType.OK)
                {
                        folder_uri = dialog.get_current_folder_uri ();
                        foreach (var uri in dialog.get_uris ())
                                uris.add (uri);
                }
                projects = uris.read_only_view;
                dialog.destroy ();
        }

        private void on_new ()
        {
                this.new_clicked ();
        }
        
        private void on_open ()
        {
                this.open_clicked ();
        }

        private void on_close ()
        {
                this.close_clicked ();
        }

        private const ActionEntry[] _action_entries =
        {
                { "ProjectsMenuAction", null, N_("_Projects") },
                { "NewProjectAction", STOCK_NEW, null, null, N_("Create a new project"), on_new },
                { "OpenProjectAction", STOCK_OPEN, null, null, N_("Open a project"), on_open },
                { "CloseProjectAction", STOCK_CLOSE, null, null, N_("Close current project"), on_close }
        };
        
        private const string _UI = """
<ui>
        <menubar name="MainMenu">
                <placeholder name="MenuBarOps">
                        <menu name="ProjectsMenu" action="ProjectsMenuAction">
                                <menuitem action="NewProjectAction"/>
                                <menuitem action="OpenProjectAction"/>
                                <separator/>
                                <menuitem action="CloseProjectAction"/>
                        </menu>
                </placeholder>
        </menubar>
</ui>""";
}