source: libi4uc/i4ucprojectsview.vala @ 4b2dccae29686a8f5267e527921cfb42df0148e1

/* i4ucprojectsview.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.ProjectsView : GLib.Object, ProjectsViewIface
{
        private UIManager _ui_manager;
        private ActionGroup _action_group;
        private SidePanel _side_panel;
        private ProjectsSidePageView _side_page_view = new ProjectsSidePageView ();
        private Action _add_file_action;
        private Action _remove_file_from_project_action;
        private Action _remove_file_from_profile_action;
        private Action _add_profile_action;
        private Action _close_action;

        public ProjectsSidePageViewIface side_page_view { get { return _side_page_view; } }
        
        public bool add_file_sensitive
        {
                set { _add_file_action.sensitive = value; }
                get { return _add_file_action.sensitive; }
        }
        
        public bool remove_file_from_project_sensitive
        {
                set { _remove_file_from_project_action.sensitive = value; }
                get { return _remove_file_from_project_action.sensitive; }
        }
        
        public bool remove_file_from_profile_sensitive
        {
                set { _remove_file_from_profile_action.sensitive = value; }
                get { return _remove_file_from_profile_action.sensitive; }
        }
        
        public bool add_profile_sensitive
        {
                set { _add_profile_action.sensitive = value; }
                get { return _add_profile_action.sensitive; }
        }
        
        public bool close_sensitive
        {
                set { _close_action.sensitive = value; }
                get { return _close_action.sensitive; }
        }
        
        public ProjectsView (UIManager ui_manager, SidePanel side_panel)
        {
                _ui_manager = ui_manager;
                _side_panel = side_panel;

                _action_group = new ActionGroup ("I4ucProjectsActions");
                _action_group.add_actions (_action_entries, this);
                
                _ui_manager.insert_action_group (_action_group, -1);
                _ui_manager.add_ui_from_string (_UI, -1);
                
                _add_file_action = _action_group.get_action ("AddFileProjectAction");
                _remove_file_from_project_action = _action_group.get_action ("RemoveFileFromProjectProjectAction");
                _remove_file_from_profile_action = _action_group.get_action ("RemoveFileFromProfileProjectAction");
                _add_profile_action = _action_group.get_action ("AddProfileProjectAction");
                _close_action = _action_group.get_action ("CloseProjectAction");

                _side_panel.add_page (_side_page_view);
        }

        public void show_error_message (string error_message)
        {
                var message = new MessageDialog (null, DialogFlags.MODAL, MessageType.ERROR, ButtonsType.NONE, error_message);
                message.add_button (STOCK_OK, ResponseType.OK);
                message.set_default_response (ResponseType.OK);
                message.run ();
                message.destroy ();
        }

        public int show_yes_no_message (string message, bool cancel)
        {
                var dialog = new MessageDialog (null, DialogFlags.MODAL, MessageType.WARNING, ButtonsType.NONE, message);
                if (cancel)
                        dialog.add_button (STOCK_CANCEL, ResponseType.CANCEL);
                dialog.add_button (STOCK_NO, ResponseType.NO);
                dialog.add_button (STOCK_YES, ResponseType.YES);
                dialog.set_default_response (ResponseType.YES);
                var response = dialog.run ();
                dialog.destroy ();
                return response;
        }

        public int show_new_dialog (out string project_uri, out string project_name, out Gee.List<string> authors)
        {
                var dialog = new NewProjectDialog ();
                var response = dialog.run ();

                project_uri = dialog.project_uri;
                project_name = dialog.project_name;
                authors = dialog.project_authors;

                dialog.destroy ();
                return response;
        }

        public void show_open_dialog (ref string folder_uri, out Gee.List<string> projects)
        {
                var dialog = new FileChooserDialog (_("Open project"), null, FileChooserAction.OPEN);
                dialog.select_multiple = true;
                dialog.set_current_folder_uri (folder_uri);
                dialog.add_button (STOCK_CANCEL, ResponseType.CANCEL);
                dialog.add_button (STOCK_OPEN, ResponseType.OK);
                dialog.set_default_response (ResponseType.OK);
                var filter = new FileFilter ();
                filter.set_name (_("i4uc projects"));
                filter.add_pattern ("*.i4uc");
                dialog.add_filter (filter);
                
                var uris = new ArrayList<string> ();
                if (dialog.run () == ResponseType.OK)
                {
                        folder_uri = dialog.get_current_folder_uri ();
                        foreach (var uri in dialog.get_uris ())
                                uris.add (uri);
                }
                projects = uris.read_only_view;
                dialog.destroy ();
        }

        public AddFileDialogViewIface create_add_file_dialog_view ()
        {
                return new AddFileDialogView ();
        }

        public AddProfileDialogViewIface create_add_profile_dialog_view ()
        {
                return new AddProfileDialogView ();
        }

        private void on_new ()
        {
                this.new_clicked ();
        }
        
        private void on_open ()
        {
                this.open_clicked ();
        }

        private void on_add_file ()
        {
                this.add_file_clicked ();
        }

        private void on_remove_file_from_project ()
        {
                this.remove_file_from_project_clicked ();
        }

        private void on_remove_file_from_profile ()
        {
                this.remove_file_from_profile_clicked ();
        }

        private void on_add_profile ()
        {
                this.add_profile_clicked ();
        }

        private void on_close ()
        {
                this.close_clicked ();
        }

        private const ActionEntry[] _action_entries =
        {
                { "ProjectsMenuAction", null, N_("_Projects") },
                { "NewProjectAction", STOCK_NEW, null, null, N_("Create a new project"), on_new },
                { "OpenProjectAction", STOCK_OPEN, null, null, N_("Open a project"), on_open },
                { "AddFileProjectAction", STOCK_ADD, N_("Add file"), null, N_("Add a file to current project"), on_add_file },
                { "RemoveFileFromProjectProjectAction", STOCK_REMOVE, N_("Remove file from project"), null, N_("Remove a file from current project"), on_remove_file_from_project },
                { "RemoveFileFromProfileProjectAction", STOCK_REMOVE, N_("Remove file from profile"), null, N_("Remove a file from current profile"), on_remove_file_from_profile },
                { "AddProfileProjectAction", STOCK_ADD, N_("Add profile"), null, N_("Add a profile to current project"), on_add_profile },
                { "CloseProjectAction", STOCK_CLOSE, null, null, N_("Close current project"), on_close }
        };
        
        private const string _UI = """
<ui>
        <menubar name="MainMenu">
                <placeholder name="MenuBarOps">
                        <menu name="ProjectsMenu" action="ProjectsMenuAction">
                                <menuitem action="NewProjectAction"/>
                                <menuitem action="OpenProjectAction"/>
                                <separator/>
                                <menuitem action="AddFileProjectAction"/>
                                <menuitem action="RemoveFileFromProjectProjectAction"/>
                                <menuitem action="RemoveFileFromProfileProjectAction"/>
                                <separator/>
                                <menuitem action="AddProfileProjectAction"/>
                                <separator/>
                                <menuitem action="CloseProjectAction"/>
                        </menu>
                </placeholder>
        </menubar>
</ui>""";
}