source: libi4uc/i4ucprojectssidepageview.vala @ cf36b3a262f09427a72acf9406f81506ecf9016b

/* i4ucprojectssidepageview.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.ProjectsSidePageView : SidePage, ProjectsSidePageViewIface
{
        private Notebook _notebook = new Notebook ();
        private ProjectsCombo _projects_combo = new ProjectsCombo ();
        private FilesList _files_list = new FilesList ();
        private ProfilesCheckList _profiles_check_list = new ProfilesCheckList ();
        private ProfilesList _profiles_list = new ProfilesList ();
        private BuildersList _builders_list = new BuildersList ();
        private string _current_profile;
        private string _current_file;

        public string current_project
        {
                set { _projects_combo.current_project = value; }
                get { return _projects_combo.current_project; }
        }

        public string current_profile { get { return _current_profile; } }
        public string current_file { get { return _current_file; } }

        public bool profiles_check_list_sensitive
        {
                set { _profiles_check_list.sensitive = value; }
                get { return _profiles_check_list.sensitive; }
        }

        public BuildersListIface builders_list { get { return _builders_list; } }
        
        public bool builders_list_sensitive
        {
                set { _builders_list.sensitive = value; }
                get { return _builders_list.sensitive; }
        }

        public ProjectsSidePageView ()
        {
                _notebook.tab_pos = PositionType.BOTTOM;

                var files_scrolled_window = new ScrolledWindow (null, null);
                files_scrolled_window.add_with_viewport (_files_list);
                files_scrolled_window.set_policy (PolicyType.NEVER, PolicyType.AUTOMATIC);
                
                var profiles_scrolled_window = new ScrolledWindow (null, null);
                profiles_scrolled_window.add_with_viewport (_profiles_list);
                profiles_scrolled_window.set_policy (PolicyType.NEVER, PolicyType.AUTOMATIC);

                var profiles_expander = new Expander (_("Profiles"));
                profiles_expander.add (_profiles_check_list);

                var builders_expander = new Expander (_("Builders"));
                builders_expander.add (_builders_list);

                var files_vbox = new VBox (false, 0);
                files_vbox.pack_start (files_scrolled_window, true, true, 0);
                files_vbox.pack_start (profiles_expander, false, false, 0);

                var profiles_vbox = new VBox (false, 0);
                profiles_vbox.pack_start (profiles_scrolled_window, true, true, 0);
                profiles_vbox.pack_start (builders_expander, false, false, 0);

                _notebook.append_page (files_vbox, new Image.from_stock (STOCK_FILE, IconSize.MENU));
                _notebook.append_page (profiles_vbox, new Image.from_stock (STOCK_DIRECTORY, IconSize.MENU));

                pack_start (_projects_combo, false, false, 2);
                pack_start (_notebook, true, true, 2);
                show_all ();

                //connect signals
                _projects_combo.project_changed.connect (() => this.project_changed ());
                _profiles_list.item_changed.connect (on_item_changed);
                _profiles_list.item_activated.connect (on_item_activated);
                _profiles_check_list.check_changed.connect ((profile, active) => this.profile_check_changed (profile, active));
                _files_list.file_changed.connect (on_file_changed);
                _files_list.file_activated.connect (() => this.file_activated ());
                _notebook.switch_page.connect (on_switch_page);
        }

        public void add_project (string project_uri, string project_name)
        {
                _projects_combo.add_project (project_uri, project_name);
        }

        public void add_profile (string profile)
        {
                _profiles_check_list.add_profile (profile, false);
                _profiles_list.add_profile (profile);
        }

        public void add_profile_file (string profile, string file)
        {
                _profiles_list.add_file (profile, file);
        }

        public void add_file (string file)
        {
                _files_list.add_file (file);
        }

        public void check_profile (string profile, bool active)
        {
                _profiles_check_list.check_profile (profile, active);
        }

        public void uncheck_all_profiles ()
        {
                _profiles_check_list.uncheck_all_profiles ();
        }

        public void remove_project (string project_uri)
        {
                _projects_combo.remove_project (project_uri);
        }

        public void remove_profile (string profile)
        {
                _profiles_list.remove_profile (profile);
        }

        public void remove_profile_file (string profile, string file)
        {
                _profiles_list.remove_file (profile, file);
        }

        public void remove_file (string file)
        {
                _files_list.remove_file (file);
        }

        public void clear_profile (string profile)
        {
                _profiles_list.clear_profile (profile);
        }

        public void clear_profiles_list ()
        {
                _profiles_check_list.clear_list ();
                _profiles_list.clear_list ();
        }

        public void clear_files_list ()
        {
                _files_list.clear_list ();
        }

        private void on_item_changed ()
        {
                if (_current_profile != _profiles_list.current_profile)
                {
                        _current_profile = _profiles_list.current_profile;
                        this.profile_selected ();
                }
                if (_current_file != _profiles_list.current_file)
                {
                        _current_file = _profiles_list.current_file;
                        this.file_selected ();
                }
        }

        private void on_item_activated ()
        {
                if (_profiles_list.current_file != null)
                        this.file_activated ();
                else
                        this.profile_activated ();
        }

        private void on_file_changed ()
        {
                if (_current_file == _files_list.current_file)
                        return;
                _current_file = _files_list.current_file;
                this.file_selected ();
        }

        private void on_switch_page (NotebookPage page, uint page_num)
        {
                switch (page_num)
                {
                        case 0:
                                if (_current_profile != null)
                                {
                                        _current_profile = null;
                                        this.profile_selected ();
                                }
                                on_file_changed ();
                                break;
                        case 1:
                                on_item_changed ();
                                break;
                }
        }
}