source: libi4uc/i4ucprojectssidepagepresenter.vala @ acc9147bf954331ae9f2f16fc044ae08936bd679

/* i4ucprojectssidepagepresenter.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.ProjectsSidePagePresenter : GLib.Object
{
        private ProjectsSidePageViewIface _view;
        private DocumentsPresenter _documents_presenter;
        private ArrayList<Project> _projects = new ArrayList<Project> ();

        public Project current_project
        {
                set { _view.current_project = value.uri; }
                owned get { return get_project_from_uri (_view.current_project); }
        }

        public Gee.List<Project> projects { owned get { return _projects.read_only_view; } }

        public ProjectsSidePagePresenter (ProjectsSidePageViewIface view, DocumentsPresenter documents_presenter)
        {
                _view = view;
                _documents_presenter = documents_presenter;

                //Configure view
                _view.tab_title = _("Projects");

                //Connect view signals
                _view.project_changed.connect (on_project_changed);
                _view.file_activated.connect (on_file_activated);
        }

        public void add_project (Project project)
        {
                if (!(project in _projects))
                {
                        _view.add_project (project.uri, project.name);
                        _projects.add (project);
                }
                _view.current_project = project.uri;
        }

        public void remove_project (Project project)
        {
                if (!(project in _projects))
                        return;
                _projects.remove (project);
                _view.remove_project (project.uri);
                if (_projects.size > 0)
                        _view.current_project = _projects[0].uri;
        }

        public void remove_all_projects ()
        {
                for (int i = _projects.size-1; i >= 0; i--)
                {
                        var project = _projects[i];
                        _projects.remove (project);
                        _view.remove_project (project.uri);
                }
        }

        private void on_project_changed ()
        {
                _view.clear_files_list ();
                _view.clear_profiles_list ();

                var current_project = get_project_from_uri (_view.current_project);
                if (current_project == null)
                        return;

                //Load files list
                foreach (var file in current_project.files)
                        _view.add_file (file);

                //Load profiles list
                foreach (var profile in current_project.profiles.values)
                {
                        _view.add_profile (profile.name);
                        foreach (var file in profile.files)
                                _view.add_profile_file (profile.name, file);
                }
        }

        private void on_file_activated ()
        {
                var document_uri = this.current_project.get_file_uri (_view.current_file);
                _documents_presenter.open_document (document_uri);
        }

        private Project? get_project_from_uri (string? project_uri)
        {
                foreach (var project in _projects)
                        if (project.uri == project_uri)
                                return project;
                return null;
        }
}