source: libi4uc/i4ucprojectssidepagepresenter.vala @ 9a6914c73481a770bff1b5d3aecebdb24db3ee5e

/* i4ucprojectssidepagepresenter.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.ProjectsSidePagePresenter : GLib.Object
{
        private ProjectsSidePageViewIface _view;
        private DocumentsPresenter _documents_presenter;
        private ArrayList<Project> _projects = new ArrayList<Project> ();
        private Project _current_project;
        private string _current_profile;

        public Project current_project
        {
                set { _view.current_project = value.uri; }
                get { return _current_project; }
        }
        
        public Gee.List<Project> projects { owned get { return _projects.read_only_view; } }

        public ProjectsSidePagePresenter (ProjectsSidePageViewIface view, DocumentsPresenter documents_presenter)
        {
                _view = view;
                _documents_presenter = documents_presenter;

                //Configure view
                _view.tab_title = _("Projects");
                _view.profiles_check_list_sensitive = false;
                _view.builders_list_sensitive = false;
                foreach (var builder in I4uc.Settings.instance.builders.keys)
                        _view.builders_list.add_builder (builder);
                _view.builders_list.linker_script_visible = false;

                //Connect view signals
                _view.project_changed.connect (on_project_changed);
                _view.profile_selected.connect (on_profile_selected);
                _view.profile_check_changed.connect (on_profile_check_changed);
                _view.file_activated.connect (on_file_activated);
                _view.file_selected.connect (on_file_selected);
                _view.builders_list.builder_changed.connect (on_builder_changed);
                _view.builders_list.device_type_changed.connect (on_device_type_changed);
                _view.builders_list.device_changed.connect (on_device_changed);
                _view.builders_list.linker_script_changed.connect (on_linker_script_changed);
        }

        public void add_project (Project project)
        {
                if (!(project in _projects))
                {
                        _view.add_project (project.uri, project.name);
                        _projects.add (project);
                }
                _view.current_project = project.uri;
        }

        public void remove_project (Project project)
        {
                if (!(project in _projects))
                        return;
                _projects.remove (project);
                _view.remove_project (project.uri);
                if (_projects.size > 0)
                        _view.current_project = _projects[0].uri;
        }

        public void remove_all_projects ()
        {
                for (int i = _projects.size-1; i >= 0; i--)
                {
                        var project = _projects[i];
                        _projects.remove (project);
                        _view.remove_project (project.uri);
                }
        }

        public void update_current_project ()
        {
                on_project_changed ();
        }

        private void on_project_changed ()
        {
                _view.clear_files_list ();
                _view.clear_profiles_list ();

                _current_project = get_project_from_uri (_view.current_project);
                if (_current_project == null)
                        return;

                //Load files list
                foreach (var file in _current_project.files)
                        _view.add_file (file);

                //Load profiles list
                foreach (var profile in _current_project.profiles.values)
                {
                        _view.add_profile (profile.name);
                        foreach (var file in profile.files)
                                _view.add_profile_file (profile.name, file);
                }
        }

        private void on_profile_selected ()
        {
                _view.builders_list_sensitive = false;
                _view.builders_list.linker_script_visible = false;

                if (_current_project == null)
                        return;
                
                _current_profile = _view.current_profile;
                if (_current_profile == null)
                        return;

                var profile = _current_project.profiles[_current_profile];
                
                _view.builders_list.current_builder = profile.builder_id;
                _view.builders_list.current_device_type = profile.device_type;
                _view.builders_list.current_device = profile.device;
                
                var builder = I4uc.Settings.instance.builders[profile.builder_id];
                if (builder != null)
                {
                        var device_type = builder.device_types[profile.device_type];
                        if (device_type != null)
                        {
                                _view.builders_list.linker_script_visible = device_type.has_linker_script;
                                if (_view.builders_list.linker_script_visible)
                                        _view.builders_list.current_linker_script = profile.linker_script;
                        }
                }
                
                _view.builders_list_sensitive = true;
        }

        private void on_profile_check_changed (string profile, bool active)
        {
                if (!_view.profiles_check_list_sensitive)
                        return;

                if (_current_project == null || _view.current_file == null)
                        return;

                if (active)
                {
                        _current_project.profiles[profile].files.add (_view.current_file);
                        _view.add_profile_file (profile, _view.current_file);
                }
                else
                {
                        _current_project.profiles[profile].files.remove (_view.current_file);
                        _view.remove_profile_file (profile, _view.current_file);
                }
                _current_project.save ();
        }

        private void on_file_activated ()
        {
                var document_uri = _current_project.get_file_uri (_view.current_file);
                _documents_presenter.open_document (document_uri);
        }

        private void on_file_selected ()
        {
                _view.profiles_check_list_sensitive = false;
                _view.uncheck_all_profiles ();

                if (_current_project == null || _view.current_file == null)
                        return;

                foreach (var profile in _current_project.profiles.values)
                        _view.check_profile (profile.name, _view.current_file in profile.files);
                _view.profiles_check_list_sensitive = true;
        }

        private void on_builder_changed ()
        {
                _view.builders_list.clear_device_types_list ();

                if (_current_project == null || _current_profile == null)
                        return;
                
                var current_builder = _view.builders_list.current_builder;
                if (_view.builders_list_sensitive)
                {
                        _current_project.profiles[_current_profile].builder_id = current_builder == null ? "" : current_builder;
                        _current_project.save ();
                }

                if (current_builder == null)
                        return;
                
                var builder = I4uc.Settings.instance.builders[current_builder];
                foreach (var device_type in builder.device_types.keys)
                        _view.builders_list.add_device_type (device_type);
        }

        private void on_device_type_changed ()
        {
                _view.builders_list.clear_devices_list ();
                _view.builders_list.linker_script_visible = false;

                if (_current_project == null || _current_profile == null)
                        return;
                
                var current_device_type = _view.builders_list.current_device_type;
                if (_view.builders_list_sensitive)
                {
                        _current_project.profiles[_current_profile].device_type = current_device_type == null ? "" : current_device_type;
                        _current_project.save ();
                }
                
                if (current_device_type == null)
                        return;

                var builder = I4uc.Settings.instance.builders[_view.builders_list.current_builder];
                var device_type = builder.device_types[current_device_type];
                foreach (var device in device_type.devices)
                        _view.builders_list.add_device (device);
                
                _view.builders_list.linker_script_visible = device_type.has_linker_script;
                if (_view.builders_list.linker_script_visible)
                        _view.builders_list.current_linker_script = _current_project.profiles[_current_profile].linker_script;
        }

        private void on_device_changed ()
        {
                if (!_view.builders_list_sensitive)
                        return;

                if (_current_project == null || _current_profile == null)
                        return;
                
                var current_device = _view.builders_list.current_device;
                _current_project.profiles[_current_profile].device = current_device == null ? "" : current_device;
                _current_project.save ();
        }
        
        private void on_linker_script_changed ()
        {
                if (!_view.builders_list_sensitive)
                        return;
                
                if (_current_project == null || _current_profile == null)
                        return;
                
                var current_linker_script = _view.builders_list.current_linker_script;
                _current_project.profiles[_current_profile].linker_script = current_linker_script == null ? "" : current_linker_script;
                _current_project.save ();
        }

        private Project? get_project_from_uri (string? project_uri)
        {
                foreach (var project in _projects)
                        if (project.uri == project_uri)
                                return project;
                return null;
        }
}