source: libi4uc/i4ucprojectspresenter.vala @ e7bab963c488e383de4d6c79887ec374f2621765

/* i4ucprojectspresenter.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */

public class I4uc.ProjectsPresenter : GLib.Object
{
        private ProjectsViewIface _view;
        private ProjectsSidePagePresenter _projects_side_page_presenter;

        public ProjectsPresenter (ProjectsViewIface view)
        {
                _view = view;

                _projects_side_page_presenter = new ProjectsSidePagePresenter (_view.projects_side_page_view);

                //Configure view
                _view.close_sensitive = false;

                //Connect view signals
                _view.new_clicked.connect (on_new_clicked);
                _view.open_clicked.connect (on_open_clicked);
                _view.close_clicked.connect (on_close_clicked);
                _view.projects_side_page_view.project_changed.connect (on_project_changed);
        }

        public void open_project (string project_uri)
        {
                var project = new Project ();
                if (project.open (project_uri))
                        _projects_side_page_presenter.add_project (project);
                else
                        _view.show_error_message (_("Error trying to open <<%s>>").printf (project_uri));
        }

        public void close_all_projects ()
        {
                _projects_side_page_presenter.remove_all_projects ();
        }

        private void on_new_clicked ()
        {
                string project_uri;
                string project_name;
                Gee.List<string> authors;
                if (_view.show_new_dialog (out project_uri, out project_name, out authors) == Gtk.ResponseType.OK)
                {
                        var project = new Project ();
                        project.name = project_name;
                        project.authors.add_all (authors);

                        var main_profile = new ProjectProfile ();
                        main_profile.name = "main";
                        project.profiles["main"] = main_profile;

                        project.save (project_uri);
                        _projects_side_page_presenter.add_project (project);
                }
        }

        private void on_open_clicked ()
        {
                var folder_uri = I4uc.Settings.instance.working_folder;
                Gee.List<string> projects;
                _view.show_open_dialog (ref folder_uri, out projects);
                I4uc.Settings.instance.working_folder = folder_uri;
                foreach (var project in projects)
                        open_project (project);
        }

        private void on_close_clicked ()
        {
                _projects_side_page_presenter.remove_project (_projects_side_page_presenter.current_project);
        }

        private void on_project_changed ()
        {
                _view.close_sensitive = _projects_side_page_presenter.current_project != null;
        }
}