source: libi4uc/i4ucproject.vala @ e20be4a7bb7f7ce258435a7e11766c564c2abbc0

/* i4ucproject.vala
 *
 * Copyright (C) 2009-2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.Project : GLib.Object
{
        private const string _I4UC_PROJECT = "i4uc project";
        
        private Document _project_file = new Document ();
        private ArrayList<string> _authors = new ArrayList<string> ();
        private ArrayList<string> _files = new ArrayList<string> ();
        private HashMap<string, ProjectProfile> _profiles = new HashMap<string, ProjectProfile> ();
        
        public string name { set; get; }
        public string uri { owned get { return _project_file.uri; } }
        public string folder_uri { owned get { return _project_file.folder; } }
        public Gee.List<string> authors { get { return _authors; } }
        public Gee.List<string> files { get { return _files; } }
        public Gee.Map<string, ProjectProfile> profiles { get { return _profiles; } }
        
        public bool open (string uri) throws GLib.Error, GLib.KeyFileError
        {
                var project_content = _project_file.load_contents (uri);
                var key_file = new KeyFile ();
                if (!key_file.load_from_data (project_content, project_content.length, KeyFileFlags.NONE) ||
                    key_file.get_start_group () != _I4UC_PROJECT)
                        return false;
                
                this.name = key_file.get_string (_I4UC_PROJECT, "name");
                
                var authors = key_file.get_string_list (_I4UC_PROJECT, "authors");
                _authors.clear ();
                foreach (var author in authors)
                        _authors.add (author);
                
                var files = key_file.get_string_list (_I4UC_PROJECT, "files");
                _files.clear ();
                foreach (var file in files)
                        _files.add (file);
                
                var profiles = key_file.get_string_list (_I4UC_PROJECT, "profiles");
                _profiles.clear ();
                foreach (var profile in profiles)
                        if (key_file.has_group (@"$profile profile"))
                                _profiles[profile] = new ProjectProfile.from_key_file (key_file, @"$profile profile");
                
                return true;
        }
        
        public void save (string? uri = null)
        {
                var key_file = new KeyFile ();
                
                key_file.set_string (_I4UC_PROJECT, "name", _name);
                key_file.set_string_list (_I4UC_PROJECT, "authors", _authors.to_array ());
                key_file.set_string_list (_I4UC_PROJECT, "files", _files.to_array ());
                key_file.set_string_list (_I4UC_PROJECT, "profiles", _profiles.keys.to_array ());
                
                foreach (var profile in _profiles.values)
                        profile.to_key_file (key_file, @"$(profile.name) profile");
                
                _project_file.save_contents (key_file.to_data (null), uri);
        }
        
        public string? get_file_uri (string file)
        {
                return File.new_for_uri (this.folder_uri).get_child_for_display_name (file).get_uri ();
        }
}