source: libi4uc/i4ucprofilebuilder.vala @ 9e8cdad59409ccd4549a03471886875f800e4ee2

/* i4ucprofilebuilder.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.ProfileBuilder : GLib.Object
{
        private Command _command = new Command ();
        private ArrayList<string> _commands = new ArrayList<string> ();
        private int _command_index = 0;
        private string _command_output;
        private ProjectProfile _profile;
        
        public bool is_building { private set; get; }
        public Project project { set; get; }

        public string profile
        {
                set { _profile = _project.profiles[value]; }
                get { return _profile.name; }
        }

        public signal void command_started (string command);
        public signal void command_finished (string output);

        public ProfileBuilder ()
        {
                _command.stopped.connect (on_command_stopped);
                _command.stdout_message_added.connect (on_message_added);
                _command.stderror_message_added.connect (on_message_added);
        }

        public void build () throws GLib.Error
        {
                if (_is_building)
                        return;
                
                var builder = I4uc.Settings.instance.builders[_profile.builder_id];
                var device_type = builder.device_types[_profile.device_type];
                
                var objects = new ArrayList<string> ();
                
                _commands.clear ();
                foreach (var source in _profile.files)
                {
                        var source_type = device_type.get_source_type_from_filename (source);
                        if (source_type == null)
                                continue;
                        
                        var object = source[0:-source_type.source_type.length] + "-" + _profile.name + source_type.object_type;
                        objects.add (object);
                        
                        var source_uri = project.get_file_uri (source);
                        var object_uri = project.get_file_uri (object);
                        
                        if (!FileUtils.test (Filename.from_uri (object_uri), FileTest.EXISTS) || check_mtime (source_uri, object_uri))
                        {
                                var command = source_type.build_command;
                                command = command.replace ("%device", _profile.device);
                                command = command.replace ("%source", "\"" + source + "\"");
                                command = command.replace ("%object", object.replace (" ", "_"));
                                
                                _commands.add (command);
                        }
                }
                
                if (objects.size == 0)
                        return;
                
                var hexfile = _project.name + "-" + _profile.name + ".hex";
                var hexfile_file = File.new_for_uri (_project.get_file_uri (hexfile));

                if (hexfile_file.query_exists (null) && _commands.size == 0)
                        return;

                var objects_string = "";
                foreach (var object in objects)
                        objects_string +=  object.replace (" ", "_") + " ";
                
                var command = device_type.build_command;
                command = command.replace ("%device", _profile.device);
                command = command.replace ("%objects", objects_string);
                command = command.replace ("%hexfile", hexfile.replace (" ", "_"));
                
                _commands.add (command);
                on_command_stopped (true);
        }
        
        public void clean () throws GLib.Error
        {
                if (_is_building)
                        return;

                var builder = I4uc.Settings.instance.builders[_profile.builder_id];
                var device_type = builder.device_types[_profile.device_type];
                
                foreach (var source in _profile.files)
                {
                        var source_type = device_type.get_source_type_from_filename (source);
                        if (source_type == null)
                                continue;
                        
                        foreach (var clean_type in source_type.clean_types)
                        {
                                var filename = source[0:-source_type.source_type.length] + "-" + _profile.name + clean_type;
                                var file = File.new_for_uri (_project.get_file_uri (filename.replace (" ", "_")));
                                if (file.query_exists (null))
                                        file.delete (null);
                        }
                }
                
                foreach (var clean_type in device_type.clean_types)
                {
                        var filename = _project.name + "-" + _profile.name + clean_type;
                        var file = File.new_for_uri (_project.get_file_uri (filename.replace (" ", "_")));
                        if (file.query_exists (null))
                                file.delete (null);
                }
        }

        public void stop ()
        {
                _commands.clear ();
                _command.stop ();
        }

        private void on_command_stopped (bool exited_ok)
        {
                if (_command_index != 0)
                        this.command_finished (_command_output);
                if (_command_index < _commands.size && exited_ok)
                {
                        var folder_file = File.new_for_uri (_project.folder_uri);
                        _command_output = "";
                        if (_command.run (_commands[_command_index], folder_file.get_path ()))
                        {
                                this.is_building = true;
                                this.command_started (_commands[_command_index]);
                                _command_index++;
                        }
                }
                else
                {
                        this.is_building = false;
                        _command_index = 0;
                }
        }

        private void on_message_added (string message)
        {
                _command_output += message + "\n";
        }

        private bool check_mtime (string newer_uri, string older_uri) throws GLib.Error
        {
                var newer_file = File.new_for_uri (newer_uri);
                var older_file = File.new_for_uri (older_uri);
                
                var newer_info = newer_file.query_info ("time::*", FileQueryInfoFlags.NONE, null);
                var older_info = older_file.query_info ("time::*", FileQueryInfoFlags.NONE, null);
                
                var newer_time = newer_info.get_attribute_uint64 (FILE_ATTRIBUTE_TIME_CHANGED);
                var newer_time_usec = newer_info.get_attribute_uint32 (FILE_ATTRIBUTE_TIME_CHANGED_USEC);
                var older_time = older_info.get_attribute_uint64 (FILE_ATTRIBUTE_TIME_CHANGED);
                var older_time_usec = older_info.get_attribute_uint32 (FILE_ATTRIBUTE_TIME_CHANGED_USEC);
                
                return (newer_time > older_time) || (newer_time == older_time && newer_time_usec > older_time_usec);
        }
}