source: libi4uc/i4ucmainwindowview.vala @ 34fbc249592793418e7eb907cccee13196e06ed6

/* i4ucmainwindowview.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.MainWindowView : Gtk.Window, MainWindowViewIface
{
        private ActionGroup _action_group;
        private UIManager _ui_manager = new UIManager ();
        private PagesPanel _pages_panel = new PagesPanel ();
        private PagesPanel _side_panel = new PagesPanel ();
        private PagesPanel _bottom_panel = new PagesPanel ();
        
        public UIManager ui_manager { get { return _ui_manager; } }
        public PagesPanel pages_panel { get { return _pages_panel; } }
        public PagesPanel side_panel { get { return _side_panel; } }
        public PagesPanel bottom_panel { get { return _bottom_panel; } }

        public bool show_side_panel_active
        {
                set { (_action_group.get_action ("ShowSidePanelAction") as ToggleAction).active = value; }
                get { return (_action_group.get_action ("ShowSidePanelAction") as ToggleAction).active; }
        }

        public bool side_panel_visible
        {
                set { _side_panel.visible = value; }
                get { return _side_panel.visible; }
        }

        public bool show_bottom_panel_active
        {
                set { (_action_group.get_action ("ShowBottomPanelAction") as ToggleAction).active = value; }
                get { return (_action_group.get_action ("ShowBottomPanelAction") as ToggleAction).active; }
        }

        public bool bottom_panel_visible
        {
                set { _bottom_panel.visible = value; }
                get { return _bottom_panel.visible; }
        }

        public MainWindowView ()
        {
                this.destroy.connect (Gtk.main_quit);
                this.delete_event.connect (() => { return this.exit_clicked (); });
                this.configure_event.connect (on_configure_event);
                this.window_state_event.connect (on_window_state_event);
                
                _action_group = new ActionGroup ("I4ucMainWindowActions");
                _action_group.set_translation_domain (Config.GETTEXT_PACKAGE);
                _action_group.add_actions (_action_entries, this);
                _action_group.add_toggle_actions (_toggle_action_entries, this);

                _ui_manager.insert_action_group (_action_group, 0);
                
                try
                {
                        _ui_manager.add_ui_from_string (_UI, -1);
                        this.icon = new Gdk.Pixbuf.from_file (Path.build_filename (Config.PIXMAPS_DIR, "icon.png"));
                }
                catch (GLib.Error e)
                {
                        warning (e.message);
                }
                
                add_accel_group (_ui_manager.get_accel_group ());
                
                var menubar = (MenuBar)_ui_manager.get_widget ("/MainMenu");
                var toolbar = (Toolbar)_ui_manager.get_widget ("/MainToolbar");
                toolbar.set_style (ToolbarStyle.ICONS);
                
                _side_panel.page_position = PagePosition.LEFT;
                _bottom_panel.page_position = PagePosition.BOTTOM;

                var vpaned = new VPaned ();
                vpaned.add1 (_pages_panel);
                vpaned.add2 (_bottom_panel);

                var hpaned = new HPaned ();
                hpaned.add1 (_side_panel);
                hpaned.add2 (vpaned);
                
                var vbox = new VBox (false, 0);
                vbox.pack_start (menubar, false, false, 0);
                vbox.pack_start (toolbar, false, false, 0);
                vbox.pack_start (hpaned, true, true, 0);
                add (vbox);
        }
        
        public void show_about_dialog (Gee.Map<string, string> app_info, Gee.List<string> authors)
        {
                var about_dialog = new AboutDialog ();
                about_dialog.program_name = app_info["program_name"];
                about_dialog.comments = app_info["comments"];
                about_dialog.version = app_info["version"];
                var authors_array = new string[authors.size + 1];
                for (int i=0; i<authors.size; i++)
                        authors_array[i] = authors[i];
                authors_array[authors.size + 1] = null;
                about_dialog.set_authors (authors_array);
                about_dialog.copyright = app_info["copyright"];
                about_dialog.website = app_info["website"];
                about_dialog.logo = this.icon;
                about_dialog.run ();
                about_dialog.destroy ();
        }
        
        public void set_size (int width, int height)
        {
                resize (width, height);
        }
        
        private bool on_configure_event (Gdk.EventConfigure event)
        {
                this.size_changed (event.width, event.height);
                return false;
        }
        
        private bool on_window_state_event (Gdk.EventWindowState event)
        {
                if (Gdk.WindowState.MAXIMIZED in event.changed_mask)
                        this.state_changed (Gdk.WindowState.MAXIMIZED in event.new_window_state);
                return false;
        }

        private void on_show_side_panel ()
        {
                this.show_side_panel_changed ();
        }

        private void on_show_bottom_panel ()
        {
                this.show_bottom_panel_changed ();
        }

        private void on_quit ()
        {
                if (!this.exit_clicked ())
                        Gtk.main_quit ();
        }
        
        private void on_about ()
        {
                this.about_clicked ();
        }
        
        private const ActionEntry[] _action_entries =
        {
                { "FileMenuAction", null, N_("_File") },
                        { "QuitAction", STOCK_QUIT, null, null, N_("Quit from i4uc"), on_quit },
                { "EditMenuAction", null, N_("_Edit") },
                { "ViewMenuAction", null, N_("_View") },
                { "HelpMenuAction", null, N_("_Help") },
                        { "AboutAction", STOCK_ABOUT, null, null, N_("About i4uc"), on_about }
        };
        
        private const ToggleActionEntry[] _toggle_action_entries =
        {
                { "ShowSidePanelAction", null, N_("Side Panel"), "F9", N_("Show or hide side panel"), on_show_side_panel, false },
                { "ShowBottomPanelAction", null, N_("Bottom Panel"), "<Control>F9", N_("Show or hide bottom panel"), on_show_bottom_panel, false }
        };

        private const string _UI = """
<ui>
        <menubar name="MainMenu">
                <menu name="FileMenu" action="FileMenuAction">
                        <placeholder name="FileMenuOps"/>
                        <separator/>
                        <menuitem action="QuitAction" />
                </menu>
                <menu name="EditMenu" action="EditMenuAction">
                        <placeholder name="EditMenuOps"/>
                </menu>
                <menu name="ViewMenu" action="ViewMenuAction">
                        <menuitem action="ShowSidePanelAction"/>
                        <menuitem action="ShowBottomPanelAction"/>
                        <separator/>
                        <placeholder name="ViewMenuOps"/>
                </menu>
                <placeholder name="MenuBarOps"/>
                <menu name="HelpMenu" action="HelpMenuAction">
                        <placeholder name="HelpMenuOps"/>
                        <separator/>
                        <menuitem action="AboutAction"/>
                </menu>
        </menubar>
        <toolbar name="MainToolbar">
                <placeholder name="ToolbarStartOps"/>
                <placeholder name="ToolbarEndOps"/>
        </toolbar>
</ui>""";
}