source: libi4uc/i4ucdocumentspresenter.vala @ 8884b7871bd5444d3a505a7d2b9075a69deae9ed

/* i4ucdocumentspresenter.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.DocumentsPresenter : GLib.Object
{
        private DocumentsViewIface _view;
        private DocumentPageViewFactory _page_view_factory;
        private DocumentPreferencesPageViewFactory _preferences_page_view_factory;
        private ArrayList <DocumentPagePresenter> _page_presenters = new ArrayList <DocumentPagePresenter> ();
        private DocumentPagePresenter _page_presenter_selected;
        private DocumentPreferencesPagePresenter _preferences_page_presenter;
        
        public DocumentsPresenter (DocumentsViewIface view, DocumentPageViewFactory page_view_factory, DocumentPreferencesPageViewFactory preferences_page_view_factory)
        {
                _view = view;
                _page_view_factory = page_view_factory;
                _preferences_page_view_factory = preferences_page_view_factory;
                
                //configure view
                _view.save_sensitive = false;
                _view.save_as_sensitive = false;
                
                //connect view signals
                _page_view_factory.unselected_page.connect (on_unselected_page_view);
                _view.new_clicked.connect (on_new_clicked);
                _view.save_clicked.connect (on_save_clicked);
                _view.save_as_clicked.connect (on_save_as_clicked);
                _view.document_preferences_clicked.connect (on_preferences_clicked);
        }
        
        private void on_unselected_page_view ()
        {
                _page_presenter_selected = null;
                _view.save_sensitive = false;
                _view.save_as_sensitive = false;
        }
        
        private void on_page_presenter_selected (DocumentPagePresenter page_presenter)
        {
                _view.save_sensitive = page_presenter.can_save;
                _view.save_as_sensitive = true;
                _page_presenter_selected = page_presenter;
        }
        
        private void on_remove_page_presenter (DocumentPagePresenter page_presenter)
        {
                _page_view_factory.remove_page (page_presenter.view);
                _page_presenters.remove (page_presenter);
        }
        
        private void on_new_clicked ()
        {
                var title = _("Unsaved file %i");
                int i = 0;
                while (get_page_view_from_title (title.printf (++i)) != null)
                        ;
                var page_view = _page_view_factory.create_page ();
                page_view.title = title.printf (i);
                page_view.tab_title = title.printf (i);
                page_view.tab_tooltip = "<b>%s</b> %s".printf (_("Name:"), title.printf (i));
                page_view.tab_image = Gtk.STOCK_NEW;
                
                var page_presenter = new DocumentPagePresenter (page_view);
                page_presenter.is_new = true;
                page_presenter.selected.connect (on_page_presenter_selected);
                page_presenter.remove_document.connect (on_remove_page_presenter);
                _page_presenters.add (page_presenter);
                
                _page_view_factory.add_page (page_view);
                _page_view_factory.show_page (page_view);
        }
        
        private void on_save_clicked ()
        {
                _page_presenter_selected.save ();
        }
        
        private void on_save_as_clicked ()
        {
                _page_presenter_selected.save_as ();
        }
        
        private void on_preferences_clicked ()
        {
                if (_preferences_page_presenter == null)
                {
                        var page_view = _preferences_page_view_factory.create_page ();
                        _preferences_page_presenter = new DocumentPreferencesPagePresenter (page_view, _page_presenters);
                        _preferences_page_view_factory.add_page (page_view);
                        _preferences_page_presenter.view.close_clicked.connect ((view) => {
                                _preferences_page_view_factory.remove_page (view);
                                _preferences_page_presenter = null;
                        });
                }
                _preferences_page_view_factory.show_page (_preferences_page_presenter.view);
        }
        
        private DocumentPageViewIface? get_page_view_from_title (string title)
        {
                foreach (var page_presenter in _page_presenters)
                        if (page_presenter.view.title == title)
                                return page_presenter.view;
                return null;
        }
}