source: libi4uc/i4ucbuilderdevicetype.vala @ 6e9e55b4c06d6ff5ffa577ade54d8fa719940394

/* i4ucbuilderdevicetype.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.BuilderDeviceType : GLib.Object
{
        private ArrayList<string> _clean_types = new ArrayList<string> ();
        private ArrayList<string> _devices = new ArrayList<string> ();
        private HashMap<string, BuilderSourceType> _source_types = new HashMap<string, BuilderSourceType> ();
        
        public string device_type { set; get; }
        public string build_command { set; get; }
        public Gee.List<string> clean_types { get { return _clean_types; } }
        public Gee.List<string> devices { get { return _devices; } }
        public Gee.Map<string, BuilderSourceType> source_types { get { return _source_types; } }
        public bool has_post_build_command { set; get; }
        public string post_build_command { set; get; }
        
        public BuilderDeviceType.from_key_file (KeyFile key_file, string group) throws GLib.Error, GLib.KeyFileError
        {
                _device_type = key_file.get_string (group, "device_type");
                _build_command = key_file.get_string (group, "build_command");
                _has_post_build_command = key_file.has_key (group, "post_build_command");
                if (_has_post_build_command)
                        _post_build_command = key_file.get_string (group, "post_build_command");
                foreach (var clean_type in key_file.get_string_list (group, "clean_types"))
                        _clean_types.add (clean_type);
                foreach (var device in key_file.get_string_list (group, "devices"))
                        _devices.add (device);
                foreach (var source_type in key_file.get_string_list (group, "source_types"))
                        if (key_file.has_group (@"$_device_type $source_type source type"))
                                _source_types[source_type] =  new BuilderSourceType.from_key_file (key_file, @"$_device_type $source_type source type");
        }
        
        public void to_key_file (KeyFile key_file, string group)
        {
                key_file.set_string (group, "device_type", _device_type);
                key_file.set_string (group, "build_command", _build_command);
                if (_has_post_build_command)
                        key_file.set_string (group, "post_build_command", _post_build_command);
                key_file.set_string_list (group, "clean_types", _clean_types.to_array ());
                key_file.set_string_list (group, "devices", _devices.to_array ());
                key_file.set_string_list (group, "source_types", _source_types.keys.to_array ());
                
                foreach (var source_type in _source_types.values)
                        source_type.to_key_file (key_file, @"$_device_type $(source_type.source_type) source type");
        }
        
        public BuilderSourceType? get_source_type_from_filename (string filename)
        {
                foreach (var source_type in _source_types.values)
                        if (filename.has_suffix (source_type.source_type))
                                return source_type;
                return null;
        }
}