source: libi4uc/i4ucbuilder.vala @ e20be4a7bb7f7ce258435a7e11766c564c2abbc0

/* i4ucbuilder.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gee;

public class I4uc.Builder : GLib.Object
{
        private const string _I4UC_BUILDER = "i4uc builder";
        
        private Document _builder_file = new Document ();
        private HashMap<string, BuilderDeviceType> _device_types = new HashMap<string, BuilderDeviceType> ();
        
        public string id { set; get; }
        public Gee.Map<string, BuilderDeviceType> device_types { get { return _device_types; } }
        
        public bool open (string uri) throws GLib.Error, GLib.KeyFileError
        {
                var builder_content = _builder_file.load_contents (uri);
                var key_file = new KeyFile ();
                if (!key_file.load_from_data (builder_content, builder_content.length, KeyFileFlags.NONE) ||
                    key_file.get_start_group () != _I4UC_BUILDER)
                        return false;
                
                this.id = key_file.get_string (_I4UC_BUILDER, "id");
                
                foreach (var device_type in key_file.get_string_list (_I4UC_BUILDER, "device_types"))
                        if (key_file.has_group (@"$device_type device type"))
                                _device_types[device_type] = new BuilderDeviceType.from_key_file (key_file, @"$device_type device type");
                
                return true;
        }
        
        public void save (string? uri = null) throws GLib.Error
        {
                var key_file = new KeyFile ();
                
                key_file.set_string (_I4UC_BUILDER, "id", _id);
                key_file.set_string_list (_I4UC_BUILDER, "device_types", _device_types.keys.to_array ());
                
                foreach (var device_type in _device_types.values)
                        device_type.to_key_file (key_file, @"$(device_type.device_type) device type");
                
                _builder_file.save_contents (key_file.to_data (null), uri);
        }
}