source: libi4uc/i4ucbottompanel.vala @ 4bb5472a2eb8e6ac900bccd22139a7b37843ef48

/* i4ucbottompanel.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.BottomPanel : Gtk.VBox, PagesPanelIface
{
        private Notebook _notebook = new Notebook ();
        private ArrayList<PageIface> _pages = new ArrayList<PageIface> ();
        private Page _current_page;
        
        public PageIface current_page { get { return _current_page; } }
        
        public BottomPanel ()
        {
                _notebook.tab_pos = PositionType.BOTTOM;
                _notebook.switch_page.connect ((panel, page, page_num) => {
                        _current_page = (_notebook.get_nth_page ((int)page_num) as Page);
                        this.page_changed (_current_page);
                });
                _notebook.page_added.connect ((panel, page, page_num) => {
                        _pages.add (page as Page);
                        this.page_added (page as Page);
                });
                _notebook.page_removed.connect ((panel, page, page_num) => {
                        _pages.remove (page as Page);
                        this.page_removed (page as Page);
                        if (_notebook.get_n_pages () == 0)
                        {
                                _current_page = null;
                                this.page_changed (_current_page);
                        }
                });
                
                pack_start (_notebook, true, true, 0);
        }

        public void add_page (PageIface page)
        {
                _notebook.append_page (page as Page, (page as Page).tab_label);
        }
        
        public void insert_page (PageIface page, int position)
        {
                _notebook.insert_page (page as Page, (page as Page).tab_label, position);
        }
        
        public void remove_page (PageIface page)
        {
                _notebook.remove_page (_notebook.page_num (page as Page));
        }
        
        public void show_page (PageIface page)
        {
                _notebook.set_current_page (_notebook.page_num (page as Page));
                (page as Page).grab_focus ();
        }
        
        public Gee.List<PageIface> list_pages ()
        {
                return _pages.read_only_view;
        }
}