source: libi4uc/i4ucauthorslist.vala @ e7bab963c488e383de4d6c79887ec374f2621765

/* i4ucauthorslist.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.AuthorsList : Gtk.VBox
{
        private ListStore _authors_store;
        private TreeView _authors_view;

        private ArrayList<string> _authors = new ArrayList<string> ();

        public Gee.List<string> authors { owned get { return _authors.read_only_view; } }

        private enum AuthorsColumns
        {
                AUTHOR,
                N_COLUMNS
        }

        public signal void author_added (string author);
        public signal void author_removed (string author);

        public AuthorsList ()
        {
                _authors_store = new ListStore (AuthorsColumns.N_COLUMNS, typeof (string));
                _authors_view = new TreeView.with_model (_authors_store);

                var column = new TreeViewColumn ();
                var renderer = new CellRendererText ();
                column.pack_start (renderer, false);
                column.add_attribute (renderer, "text", AuthorsColumns.AUTHOR);
                _authors_view.append_column (column);
                _authors_view.set_headers_visible (false);

                var add_author_button = new Button.from_stock (STOCK_ADD);
                var remove_author_button = new Button.from_stock (STOCK_REMOVE);

                var buttons_vbox = new VBox (false, 0);
                buttons_vbox.pack_start (add_author_button, false, false, 2);
                buttons_vbox.pack_start (remove_author_button, false, false, 2);

                var authors_hbox = new HBox (false, 0);
                authors_hbox.pack_start (_authors_view, true, true, 2);
                authors_hbox.pack_start (buttons_vbox, false, false, 0);

                pack_start (authors_hbox, true, true, 2);

                add_author_button.clicked.connect (on_add_author);
                remove_author_button.clicked.connect (on_remove_author);
        }

        private void on_add_author ()
        {
                var dialog = new Dialog ();
                dialog.title = _("Add new author");
                var label = new Label (_("Insert new author name:"));
                dialog.vbox.pack_start (label, false, false, 5);
                var entry = new Entry ();
                dialog.vbox.pack_start (entry, true, true, 5);
                dialog.vbox.show_all ();
                dialog.add_button (STOCK_CANCEL, ResponseType.CANCEL);
                dialog.add_button (STOCK_OK, ResponseType.OK);
                dialog.set_default_response (ResponseType.OK);

                if (dialog.run () == ResponseType.OK)
                {
                        TreeIter iter;
                        _authors_store.append (out iter);
                        _authors_store.set (iter, AuthorsColumns.AUTHOR, entry.text);
                        _authors.add (entry.text);
                        this.author_added (entry.text);
                }
                dialog.destroy ();
        }

        private void on_remove_author ()
        {
                TreeIter iter;
                if (_authors_view.get_selection ().get_selected (null, out iter))
                {
                        string author;
                        _authors_store.get (iter, AuthorsColumns.AUTHOR, out author);
                        _authors_store.remove (iter);
                        _authors.remove (author);
                        this.author_removed (author);
                }
        }
}