source: libi4uc/i4ucaddprofiledialogpresenter.vala @ 4b2dccae29686a8f5267e527921cfb42df0148e1

/* i4ucaddprofiledialogpresenter.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */

public class I4uc.AddProfileDialogPresenter : GLib.Object
{
        private AddProfileDialogViewIface _view;
        private Project _project;
        private string _last_project;

        public AddProfileDialogPresenter (AddProfileDialogViewIface view, Project project)
        {
                _view = view;
                _project = project;

                //Configure view
                _view.warning_message_visible = false;
                _view.import_project_sensitive = false;
                _view.import_profile_sensitive = false;
                _view.accept_sensitive = false;
                _view.folder_uri = _project.folder_uri;

                //Connect view signals
                _view.is_new_changed.connect (on_is_new_changed);
                _view.new_profile_changed.connect (on_new_profile_changed);
                _view.import_project_changed.connect (on_import_project_changed);
                _view.import_profile_changed.connect (on_import_profile_changed);
        }

        public bool run ()
        {
                var response = _view.run ();
                var is_new = _view.is_new;
                var project_uri = _view.project_uri;
                var profile_name = _view.profile_name;
                var profile = new ProjectProfile ();
                profile.name = profile_name;
                _view.close_dialog ();

                if (response != Gtk.ResponseType.OK)
                        return false;

                if (!is_new)
                {
                        var import_project = new Project ();
                        import_project.open (project_uri);
                        if (_project.folder_uri != import_project.folder_uri)
                        {
                                var message = _("The files are outside the project's folder, do you want to copy the files?");
                                if (_view.show_yes_no_message (message, false) == Gtk.ResponseType.NO)
                                        return false;

                                var file_in_project = false;
                                foreach (var file in import_project.profiles[profile_name].files)
                                        if (file in _project.files)
                                                file_in_project = true;
                                if (file_in_project)
                                {
                                        _view.show_error_message (_("One of the files to copy already exists in the project"));
                                        return false;
                                }

                                foreach (var file in import_project.profiles[profile_name].files)
                                {
                                        var orig_file = File.new_for_uri (import_project.get_file_uri (file));
                                        var dest_file = File.new_for_uri (_project.get_file_uri (file));
                                        message = _("Do you want to overwrite the file <<%s>>?").printf (dest_file.get_path ());
                                        if (dest_file.query_exists (null) && _view.show_yes_no_message (message, false) == Gtk.ResponseType.NO)
                                                continue;
                                        orig_file.copy (dest_file, FileCopyFlags.OVERWRITE, null, null);
                                        _project.files.add (file);
                                        profile.files.add (file);
                                }
                        }
                        else
                        {
                                foreach (var file in import_project.profiles[profile_name].files)
                                {
                                        _project.files.add (file);
                                        profile.files.add (file);
                                }
                        }
                }
                _project.profiles[profile_name] = profile;
                _project.save ();
                return true;
        }

        private void on_is_new_changed ()
        {
                var is_new = _view.is_new;
                _view.new_profile_sensitive = is_new;
                _view.import_project_sensitive = !is_new;
                _view.import_profile_sensitive = !is_new;
                if (is_new)
                        on_new_profile_changed ();
                else
                {
                        on_import_project_changed ();
                        on_import_profile_changed ();
                }
        }

        private void on_new_profile_changed ()
        {
                var profile_name = _view.profile_name;
                _view.accept_sensitive = !(profile_name == "" ||
                                           profile_name.has_prefix (".") ||
                                           profile_name in _project.profiles.keys);
                if (profile_name in _project.profiles.keys)
                        _view.warning_message = _("The profile already exists in the project");
                _view.warning_message_visible = profile_name in _project.profiles.keys;
        }

        private void on_import_project_changed ()
        {
                _view.import_profile_sensitive = false;
                _view.accept_sensitive = false;
                if (_view.project_uri == "" || _view.project_uri == null)
                        return;
                if (_view.project_uri == _project.uri)
                {
                        _view.warning_message = _("Can't choose the same project");
                        _view.warning_message_visible = true;
                        return;
                }

                if (_view.project_uri != _last_project)
                {
                        var import_project = new Project ();
                        if (!import_project.open (_view.project_uri))
                        {
                                _view.warning_message = _("Can't open the project");
                                _view.warning_message_visible = true;
                                return;
                        }
        
                        _view.clear_profiles_list ();
                        _view.add_profiles (import_project.profiles.keys);
                        _last_project = _view.project_uri;
                }

                _view.warning_message_visible = false;
                _view.import_profile_sensitive = true;
                _view.accept_sensitive = true;
        }

        private void on_import_profile_changed ()
        {
                _view.accept_sensitive = false;
                if (_view.profile_name == "" || _view.profile_name == null)
                        return;
                if (_view.profile_name in _project.profiles.keys)
                {
                        _view.warning_message = _("There's already a profile with that name");
                        _view.warning_message_visible = true;
                        return;
                }

                _view.warning_message_visible = false;
                _view.accept_sensitive = true;
        }
}