source: libi4uc/i4ucaddfiledialogview.vala @ 222b8db664140ef6c8b5015a5ca71167687ffe92

/* i4ucaddfiledialogview.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.AddFileDialogView : Gtk.Dialog, AddFileDialogViewIface
{
        private InfoBar _file_in_project_info_bar = new InfoBar ();
        private RadioButton _new_file_radio = new RadioButton.with_label (null, _("New file:"));
        private Entry _new_file_entry = new Entry ();
        private RadioButton _import_file_radio;
        private FileChooserButton _import_file_chooser = new FileChooserButton (_("Select file to import to current project"), FileChooserAction.OPEN);
        private ProfilesCheckList _profiles_check_list = new ProfilesCheckList ();
        private Button _accept_button;

        public bool is_new { get { return _new_file_radio.active; } }

        public string filename
        {
                owned get
                {
                        if (this.is_new)
                                return _new_file_entry.text;
                        return _import_file_chooser.get_uri ();
                }
        }

        public string folder_uri
        {
                set { _import_file_chooser.set_current_folder_uri (value); }
                owned get { return _import_file_chooser.get_current_folder_uri (); }
        }

        public Gee.List<string> activated_profiles { owned get { return _profiles_check_list.activated_profiles; } }

        public bool file_in_project_visible
        {
                set { _file_in_project_info_bar.visible = value; }
                get { return _file_in_project_info_bar.visible; }
        }

        public bool new_file_sensitive
        {
                set { _new_file_entry.sensitive = value; }
                get { return _new_file_entry.sensitive; }
        }

        public bool import_file_sensitive
        {
                set { _import_file_chooser.sensitive = value; }
                get { return _import_file_chooser.sensitive; }
        }

        public bool accept_sensitive
        {
                set { _accept_button.sensitive = value; }
                get { return _accept_button.sensitive; }
        }
        
        public AddFileDialogView ()
        {
                this.title = _("Add file to project");

                var info_bar_content = _file_in_project_info_bar.get_content_area () as Container;
                info_bar_content.add (new Label (_("The file is already added to the project")));
                this.vbox.pack_start (_file_in_project_info_bar, false, false, 5);

                var hbox = new HBox (false, 0);
                hbox.pack_start (_new_file_radio, false, false, 5);
                hbox.pack_start (_new_file_entry, true, true, 5);
                this.vbox.pack_start (hbox, true, true, 5);

                _import_file_radio = new RadioButton.with_label_from_widget (_new_file_radio, _("Import file:"));
                _import_file_chooser.sensitive = false;

                hbox = new HBox (false, 0);
                hbox.pack_start (_import_file_radio, false, false, 5);
                hbox.pack_start (_import_file_chooser, true, true, 5);
                this.vbox.pack_start (hbox, true, true, 5);

                this.vbox.pack_start (new Label (_("Add file to profile:")), false, false, 5);
                this.vbox.pack_start (_profiles_check_list, true, true, 5);

                add_button (STOCK_CANCEL, ResponseType.CANCEL);
                _accept_button = add_button (STOCK_OK, ResponseType.OK) as Button;
                set_default_response (ResponseType.OK);
                this.vbox.show_all ();

                _new_file_radio.toggled.connect (() => this.is_new_changed ());
                _new_file_entry.changed.connect (() => this.new_file_changed ());
                _import_file_chooser.file_set.connect (() => this.import_file_changed ());
        }

        public void add_profiles (Collection<string> profiles)
        {
                foreach (var profile in profiles)
                        _profiles_check_list.add_profile (profile, false);
        }

        public int show_yes_no_message (string message, bool cancel)
        {
                var dialog = new MessageDialog (null, DialogFlags.MODAL, MessageType.WARNING, ButtonsType.NONE, message);
                if (cancel)
                        dialog.add_button (STOCK_CANCEL, ResponseType.CANCEL);
                dialog.add_button (STOCK_NO, ResponseType.NO);
                dialog.add_button (STOCK_YES, ResponseType.YES);
                dialog.set_default_response (ResponseType.YES);
                var response = dialog.run ();
                dialog.destroy ();
                return response;
        }

        public void close_dialog ()
        {
                close ();
        }
}