source: gtkfrontend/projectsview.vala @ 628f3dc614aeb64636b8b50cb2c7413053d2e490

/* projectsview.vala
 *
 * Copyright (C) 2010  Matias De la Puente
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Author:
 *      Matias De la Puente <mfpuente.ar@gmail.com>
 */
using Gtk;
using Gee;

public class I4uc.GtkFrontend.ProjectsView : GLib.Object, I4uc.Core.ProjectsView
{
        private UIManager _ui_manager;
        private ActionGroup _action_group;
        private PagesPanel _side_panel;
        private PagesPanel _bottom_panel;
        private ProjectsPageView _page_view = new ProjectsPageView ();
        private ProfileBuilderLogPage _build_log_page = new ProfileBuilderLogPage ();

        public I4uc.Core.ProjectsPageView page_view { get { return _page_view; } }
        
        public I4uc.Core.ProfileBuilderLogPage build_log_page { get { return _build_log_page; } }
        
        public bool add_file_sensitive
        {
                set { _action_group.get_action ("AddFileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("AddFileProjectAction").sensitive; }
        }
        
        public bool remove_file_from_project_sensitive
        {
                set { _action_group.get_action ("RemoveFileFromProjectProjectAction").sensitive = value; }
                get { return _action_group.get_action ("RemoveFileFromProjectProjectAction").sensitive; }
        }
        
        public bool remove_file_from_profile_sensitive
        {
                set { _action_group.get_action ("RemoveFileFromProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("RemoveFileFromProfileProjectAction").sensitive; }
        }
        
        public bool add_profile_sensitive
        {
                set { _action_group.get_action ("AddProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("AddProfileProjectAction").sensitive; }
        }
        
        public bool edit_profile_sensitive
        {
                set { _action_group.get_action ("EditProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("EditProfileProjectAction").sensitive; }
        }
        
        public bool duplicate_profile_sensitive
        {
                set { _action_group.get_action ("DuplicateProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("DuplicateProfileProjectAction").sensitive; }
        }
        
        public bool remove_profile_sensitive
        {
                set { _action_group.get_action ("RemoveProfileFromProjectProjectAction").sensitive = value; }
                get { return _action_group.get_action ("RemoveProfileFromProjectProjectAction").sensitive; }
        }
        
        public bool build_profile_sensitive
        {
                set { _action_group.get_action ("BuildProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("BuildProfileProjectAction").sensitive; }
        }
        
        public bool program_profile_sensitive
        {
                set { _action_group.get_action ("ProgramProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("ProgramProfileProjectAction").sensitive; }
        }
        
        public bool stop_sensitive
        {
                set { _action_group.get_action ("StopProjectAction").sensitive = value; }
                get { return _action_group.get_action ("StopProjectAction").sensitive; }
        }
        
        public bool clean_profile_sensitive
        {
                set { _action_group.get_action ("CleanProfileProjectAction").sensitive = value; }
                get { return _action_group.get_action ("CleanProfileProjectAction").sensitive; }
        }
        
        public bool close_sensitive
        {
                set { _action_group.get_action ("CloseProjectAction").sensitive = value; }
                get { return _action_group.get_action ("CloseProjectAction").sensitive; }
        }
        
        public ProjectsView (UIManager ui_manager, PagesPanel side_panel, PagesPanel bottom_panel)
        {
                _ui_manager = ui_manager;
                _side_panel = side_panel;
                _bottom_panel = bottom_panel;

                _action_group = new ActionGroup ("I4ucProjectsActions");
                _action_group.set_translation_domain (Config.GETTEXT_PACKAGE);
                _action_group.add_actions (_action_entries, this);
                
                _ui_manager.insert_action_group (_action_group, -1);
                
                try
                {
                        _ui_manager.add_ui_from_string (_UI, -1);
                }
                catch (GLib.Error e)
                {
                        warning (e.message);
                }
                
                var toolbar = (Toolbar)_ui_manager.get_widget ("/MainToolbar");
                toolbar.set_style (ToolbarStyle.ICONS);
                
                _side_panel.insert_page (_page_view, 0);
                _side_panel.show_page (_page_view);
                _bottom_panel.add_page (_build_log_page);
        }

        public void show_error_message (string error_message)
        {
                var message = new MessageDialog (null, DialogFlags.MODAL, MessageType.ERROR, ButtonsType.NONE, error_message);
                message.add_button (STOCK_OK, ResponseType.OK);
                message.set_default_response (ResponseType.OK);
                message.run ();
                message.destroy ();
        }

        public int show_yes_no_message (string message, bool cancel)
        {
                var dialog = new MessageDialog (null, DialogFlags.MODAL, MessageType.WARNING, ButtonsType.NONE, message);
                if (cancel)
                        dialog.add_button (STOCK_CANCEL, ResponseType.CANCEL);
                dialog.add_button (STOCK_NO, ResponseType.NO);
                dialog.add_button (STOCK_YES, ResponseType.YES);
                dialog.set_default_response (ResponseType.YES);
                var response = dialog.run ();
                dialog.destroy ();
                return response;
        }

        public int show_new_dialog (out string project_uri, out string project_name, out Gee.List<string> authors)
        {
                var dialog = new NewProjectDialog ();
                var response = dialog.run ();

                project_uri = dialog.project_uri;
                project_name = dialog.project_name;
                authors = dialog.project_authors;

                dialog.destroy ();
                return response;
        }

        public I4uc.Core.AddFileDialogView create_add_file_dialog_view ()
        {
                return new AddFileDialogView ();
        }

        public I4uc.Core.AddProfileDialogView create_add_profile_dialog_view ()
        {
                return new AddProfileDialogView ();
        }
        
        public void show_build_log_page ()
        {
                _bottom_panel.show_page (_build_log_page);
        }
        
        public void add_recent (string uri)
        {
                RecentManager.get_default ().add_item (uri);
        }

        private void on_new ()
        {
                this.new_clicked ();
        }
        
        private void on_add_file ()
        {
                this.add_file_clicked ();
        }

        private void on_remove_file_from_project ()
        {
                this.remove_file_from_project_clicked ();
        }

        private void on_remove_file_from_profile ()
        {
                this.remove_file_from_profile_clicked ();
        }

        private void on_add_profile ()
        {
                this.add_profile_clicked ();
        }
        
        private void on_edit_profile ()
        {
                this.edit_profile_clicked ();
        }
        
        private void on_duplicate_profile ()
        {
                this.duplicate_profile_clicked ();
        }

        private void on_remove_profile ()
        {
                this.remove_profile_clicked ();
        }
        
        private void on_build_profile ()
        {
                this.build_profile_clicked ();
        }
        
        private void on_program_profile ()
        {
                this.program_profile_clicked ();
        }
        
        private void on_stop ()
        {
                this.stop_clicked ();
        }

        private void on_clean_profile ()
        {
                this.clean_profile_clicked ();
        }
        
        private void on_close ()
        {
                this.close_clicked ();
        }

        private const ActionEntry[] _action_entries =
        {
                { "ProjectsMenuAction", null, N_("_Projects") },
                { "NewProjectAction", STOCK_NEW, null, "<Control><Shift>n", N_("Create a new project"), on_new },
                { "AddFileProjectAction", STOCK_ADD, N_("Add file"), null, N_("Add a file to current project"), on_add_file },
                { "RemoveFileFromProjectProjectAction", STOCK_REMOVE, N_("Remove file from project"), null, N_("Remove a file from current project"), on_remove_file_from_project },
                { "RemoveFileFromProfileProjectAction", STOCK_REMOVE, N_("Remove file from profile"), null, N_("Remove a file from current profile"), on_remove_file_from_profile },
                { "AddProfileProjectAction", STOCK_ADD, N_("Add profile"), null, N_("Add a profile to current project"), on_add_profile },
                { "EditProfileProjectAction", STOCK_EDIT, N_("Edit profile"), null, N_("Edit current profile"), on_edit_profile },
                { "DuplicateProfileProjectAction", STOCK_COPY, N_("Duplicate profile"), "<Control>d", N_("Duplicate current profile"), on_duplicate_profile },
                { "RemoveProfileFromProjectProjectAction", STOCK_REMOVE, N_("Remove profile from project"), null, N_("Remove a profile from current project"), on_remove_profile },
                { "BuildProfileProjectAction", STOCK_EXECUTE, N_("Build profile"), "<Control><Shift>b", N_("Build current profile"), on_build_profile },
                { "ProgramProfileProjectAction", STOCK_MEDIA_RECORD, N_("Program profile"), "<Control><Shift>p", N_("Program current profile"), on_program_profile },
                { "StopProjectAction", STOCK_STOP, N_("Stop"), "", N_("Stop building current profile"), on_stop },
                { "CleanProfileProjectAction", STOCK_CLEAR, N_("Clean profile"), null, N_("Clean current profile"), on_clean_profile },
                { "CloseProjectAction", STOCK_CLOSE, null, null, N_("Close current project"), on_close }
        };
        
        private const string _UI = """
<ui>
        <menubar name="MainMenu">
                <placeholder name="MenuBarOps">
                        <menu name="ProjectsMenu" action="ProjectsMenuAction">
                                <menuitem action="NewProjectAction"/>
                                <separator/>
                                <menuitem action="AddFileProjectAction"/>
                                <menuitem action="RemoveFileFromProjectProjectAction"/>
                                <menuitem action="RemoveFileFromProfileProjectAction"/>
                                <separator/>
                                <menuitem action="AddProfileProjectAction"/>
                                <menuitem action="EditProfileProjectAction"/>
                                <menuitem action="DuplicateProfileProjectAction"/>
                                <menuitem action="RemoveProfileFromProjectProjectAction"/>
                                <separator/>
                                <menuitem action="BuildProfileProjectAction"/>
                                <menuitem action="StopProjectAction"/>
                                <menuitem action="CleanProfileProjectAction"/>
                                <menuitem action="ProgramProfileProjectAction"/>
                                <separator/>
                                <menuitem action="CloseProjectAction"/>
                        </menu>
                </placeholder>
        </menubar>
        <toolbar name="MainToolbar">
                <placeholder name="ToolbarEndOps">
                        <separator/>
                                <toolitem action="BuildProfileProjectAction"/>
                                <toolitem action="StopProjectAction"/>
                                <toolitem action="ProgramProfileProjectAction"/>
                        <separator/>
                </placeholder>
        </toolbar>
</ui>""";
}